ЄС-11

Цифрова комутаційна система

Науково-виробничий центр
"Автоматизовані мікропроцесорні системи"
ЄДРПОУ: 13807402 тел: +380-32-237-21-36

Користувальницькькі налаштування

Налаштування сайту


es11soft:groupconfig:comopis

Створення узагальненого опису комутатора

Нижче приведено приклад створення опису комутатора районного масштабу. Комутатор описується як єдине ціле - (з одним поінт-кодом в національній мережі) - без поділу на функціональні одиниці. Тільки опис підключення потоків спирається на дворівневу модель комутатора (Cross374) - допускаються як безпосередньо-комутовані так і транзитно-підняті потоки. В усьому іншому (канали, нумерація, тощо) опис повністю абстрагується від внутрішньої структури комутатора. Зокрема, не потребує детального опису і підключення по ОКСу - тонал-сети, лінк-сети та маршрутизація згадуються тільки ескізно.

Вважається, що цей приклад опису в подальшому буде оброблятися програмою побудови секційних описів BuildSwitch або їй подібною.

Вибір назви та поінт-коду

Створення опису комутатора (або проекту) починається з вибору назви для комутатора; бажано щоби назва комутатора відповідала номеру проекту, що надавався при запуску, або назві населеного пункту розташування комутатора; приклади назв:

  133, 008, 914 ;
  TBN, Yare, Monk019, Tetijiv, Teti169 ;

Ця назва в подальшому буде використовуватись при побудові таблиць маршрутів комутатора. Аналогічно, цю назву можна використовувати як фрагмент назви текстових файлів з узагальненим описом комутатора, наприклад:

  • Tetijiv - назва всього проекту та головного комутатора;
  • Teti170 та Teti171 - комутатори-виноси;

Приклади назви файлів з описом комутатора та його частин: Tetijiv.Prj, Tetijiv-Numeration.Prj, Teti171.Prj, тощо.

Назву комутатора можна явно відв'язати від назви файлу, де він описаний; щоби явно вказати назву комутатора використовується директива Model з параметром Name:

  Model:    Name = Tetijiv

При такому визначення назви комутатора нема потреби, щоби ця назва співпадала з назвою головного вхідного файлу.

Визначення поінт-коду комутатора

Поінт-код комутатора в національній мережі визначається директивою:

  DefinePointCode  Tetijiv, Nat 17, 3, 3	;;наш код

Ця директива визначає визначає поінт-код вузла Tetijiv в національній мережі - Nat . Зверніть увагу, що назва вузла (Tetijiv) повинна співпадати з назвою проекту та може співпадати назвою файлу опису комутатора (Tetijiv.Prj).

Ця ж директива визначає і базовий поінт-код складових частин (секцій) комутатора.

Визначення зонового номеру комутатора

Зоновий номер комутатора - це номер в міжнародній мережі; наприклад, з точністю до п'яти цифр - 380-4554-xxxxx - номер типовий для району. В подальшому описі, з цих цифр повинні починатись перевірки АВН та описи параметрів транків районного комутатора. Для визначення зонового номера самого комутатора використовується директива:

  TrunkExtraPar Tetijiv,"380-4455-5xxxx",<49.377902,29.668550>;Україна,Київська область,Тетіїв

Ця ж директива визначає і географічні координати самого комутатора.

Визначення моделі комутатора

Також, необхідно вказати модель (тип кросу) комутатора:

  Model:    Type     = 374         ;; тип комутатора

Ця директива прив'язує весь подальший опис потоків та каналів комутатора до кросу 374.

Визначення базового поінт-коду секцій

Для побудови внутрішніх маршрутів (особливо, маршрутів діагностики) між секціями комутатора, всі ці секції отримують різні поінт-коди, які залежать від базового поінт-коду самого комутатора; а саме: секція A отримує код базовий+1, секція B - базовий+2, і т.п. По замовчуванню, базовий поінт-код комутатора ідентичний його поінт-коду в мережі, що визначений директивою DefinePointCode. Для зміни базового поінт-коду та визначення діапазону допустимих поінт-кодів для секцій використовується директива:

  Model:    BasicPC  = <0-4-0>,+15 ;;

Ця директива визначає базовий поінт-код та діапазон поінт-кодів для складових частин комутатора.

Опис підключення до інших станцій

Підключення до станцій верхнього рівня по ОКСу

Необхідно детально описати параметри зовнішніх вузлів, приклад:

ConnectOksNode  INTR, <Nat,20, 1, 0>, <C6>,       < >,  <OPTS,AMTS>	; вихід на INTR
ConnectOksNode  PGW2, <Nat,16, 7, 2>, <G3,G4>,    < >,  <AMTS,OPTS>	; вихід на PGW2
ConnectOksNode  AMTS, <Nat, 9, 0, 0>, <D1,C4>,    <D11>,     <OPTS>	; вихід на AMTS	
ConnectOksNode  OPTS, <Nat, 9, 5, 1>, <C1,C2,D3>, <C11,D31>, <AMTS>	; вихід на OPTS

В цих директивах, після назви вузла (наприклад INTR) вказано:

  • дескриптор мережі (Nat) та поінт-код вузла в цій мережі;
  • перелік потоків підключення, використовується для побудови тонал-сетів та роздачі CIC;
  • перелік ланок сигналізації для побудови лінк-сетів; для вузлів, робота з якими ведеться в квази-зв'язаному режимі, цей список пустий;
  • перелік вузлів для резервних маршрутів; використовується для побудови спільних таблиць маршрутизації;

Зверніть увагу, в напрямку вузлів, підключених директивою ConnectOksNode, передача повідомлень діагностики блокована.

Опис каналів та номерної ємності буде приведено нижче.

Підключення підлеглих станцій та БАДів по ОКСу

Визначення вузлів та конфігурації підключення, мережа та поінт-код вказується безпосередньо в директиві:

  ConnectOksNode  Bad1, <Zon, 3, 0, 0>, <H1,H2>, <H1G,H2G>
  ConnectOksNode  Bad2, <Zon, 3, 1, 0>, <I1,I2>, <I1G,I2G>

З підлеглими вузлами робота ведеться як правило в мережі Zon - індикатор такої мережі можна не вказувати.

Або як-що поінт-коди цих вузлів були визначені раніше відповідними директивами DefinePointCode:

  ConnectOksPeer  Bad3, < >,    <H3,I4>,       <H3G,I4G>
  ConnectOksPeer  Bad4, < >,    <H4,I3>,       <H4G,I3G>
  ConnectOksPeer  Berd,    ,  <M1,M2,M3,M4>, <M11>

Як правило, для вузлів в локальній мережі, список вузлів для резервних маршрутів пустий. Зверніть увагу, в напрямку вузлів, підключених директивою ConnectOksPeer, повідомлення діагностики передаються.

Приклад підключення двох підлеглих вузлів - один з них (Yam2) не має прямих ланок сигналізації та використовує ресурси вузла Poly:

  ;; підключення до сусіднього комутатора
  ConnectOksNode  Poly, < >, <K1,G2,K3,G4>,<K11,G21>
  ConnectOksNode  Yam2, < >, <K5,G6>,      < >,      <Poly>

Приклад підключення підлеглого комутатора з БАДами:

  ConnectOksPeer  Teti171, < 600>, <L2,M1,N2,N3>,<L21,M11>
      RedirectOksDiag  Teti171, 171Bad1 +3          

Зверніть увагу, при такому підключенні вузол Teti171 забезпечує транзит повідомлень діагностики в діапазоні від 171Bad1 до 171Bad1+3.

Приклад підключення до Bad7 (з поінт-кодом Zon,460) двома незалежними тонал-сетами та лінк-сетами:

  ConnectOksPeer  Bad7, < 460 >, <L6>, <L6G>
  ConnectOksPeer  Bad7,        , <M5>, <M5G>

Примітка: - така схема підключення - один потік - один лінк - найбільш ефективна в плані відсутності зайвої передачі повідомлень між лінками.

В усіх попередніх прикладах комутатор працює з зустрічними станціями одним поінт-кодом, який попередньо присвоєний цьому комутатору. У прикладі:

  ConnectOksPeer  Bad8, <470>/SecA, <L5>, <L5G>
  ConnectOksPeer  Bad8, <470>/SecB, <M6>, <M6G>

комутатор працює з вузлом Bad8 (з поінт-кодом Zon,470) двома різними поінт-кодами SecA та SecB відповідно. Така мульти-адресна схема використовується для підключення обладнання застарілих типів.

Ще один приклад:

  ConnectOksPeer  Bad7, +100 , <L6>, <L6G>

Тут вказано, що вузлу Bad7 призначено поінт-код на 100 більший, ніж для самого комутатора.

Підключення до віддаленого вузла діагностики

Мережа діагностики охоплює сам комутатор та підлеглі до нього вузли та БАДи. Ця мережа накладається на внутрішню мережу передачі повідомлень сигналізації ОКС - идентифікатор мережі Zon. В якості порталів мережі діагностики використовуються COM та IP порти процесорів комутатора. Підключення цих портів до мережі описувати не треба.

Для підключення до віддаленого вузла діагностики (наприклад, по протоколу типу FrameRelay) можна використовувати окрему одноканальну ланку сигналізації розміщену в одному з зовнішніх потоків. Приклад опису такої ланки та спряженого з нею вузла діагностики oCUD:

    SetLinkModes   <C6V>,     -T1L
    ConnectOksPeer oCUD, <Zon, 9,17, 1>, < >,<C6V>

В цих директивах вказано канал розміщення ланки - C6V - та поінт-код вузла діагностики у внутрішній мережі комутатора.

Опис підключення лінків по ОКСу

Ланки сигналізації, якщо вони працюють в однакових режимах, можна описати однією директивою:

  SetLinkModes <C11,D11,D31>, -T1

де -T1 - режим роботи лінків.

Опис підключення потоків по ОКСу

Звичайні, комутовані потоки ОКСу також можна описати однією директивою:

  GroupOksIkm   <C1,C2,C4,C6, D1,D3, G3,G4>, H	;; вісім потоків міжміста

або по одному потоку:

  AlloctOksIkm   C,1, H	;;
  AlloctOksIkm   C,2, H	;;

Увага: такі звичайні, комутовані потоки ОКСу не використовуються в моделі комутатора 374.

В моделі комутатора 374 використовуються транзитно-підняті потоки, які описуються директивою:

  AlloctOksPass H,3,C ;; BAD1
  AlloctOksPass I,4,C ;; BAD1

При не типовій схемі підняття потоку або використанні не всіх каналів в потоці:

  ; підключення BAD'ів - двома трактами з лінками /G/ - НЕ всі канали - по 20
  AlloctOksPass G,1,C--,0A,8--,32, <-123456789ABCDEF-HIJKL----------> ; BAD7
  AlloctOksPass K,2,C--,0G,8--,32, <-123456789ABCDEF-HIJKL----------> ; BAD7

Для сумісності зі старими описами можна використовувати директиву AlloctOksHway, яка повністю ідентична директиві AlloctOksPass.

Підключення станцій з PRI-сигналізацією

Приклад підключення двох трактів з Pri-сигналізацією - у другому задіяно тільки 10 тональних каналів:

  DefinePriIkm	G, 3, H--	;; Karp   Pri !!
  DefinePriIkm	M, 3, H--, 10	;; Depo Pri тільки десять каналів

В кожному потоці використовується ланка сигналізації:

  SetLinkModes <G5G,M3G>,     -T1N	;; /U

Опис потоків з PRI-сигналізацією не потребує додаткових директив опису вузлів - кожний вузол складається з одного потоку та відповідної ланки сигналізації.

Підключення станцій з CAS-сигналізацією

Визначення декількох звичайних комутованих трактів, що працюють в однакових режимах:

  GroupCasIkm    <E4,F4, F1, F2>,  HP2 ;; MIK, YAM, OPM

або по одному потоку:

  AlloctCasIkm   E,4, HP2 ;; MIK
  AlloctCasIkm   F,4, HP2 ;; MIK

Два транзитно підняті тракти, характерні для моделі 374:

  AlloctHwa    E, 3, HI2N ;; VOR
  AlloctHwa    F, 3, HI2N ;; VOR

теж-саме з стандартним підняттям та не типовим переліком каналів:

  AlloctHwa    E, 3, HI2N, , , 32, <-123456789ABCDEF-HIJKLMNOP------>	;; VOR
  AlloctHwa    F, 3, HI2N, , , 32, <-123456789ABCDEF-HIJKLMNOP------>	;; VOR

І нарешті: один тракт - піднятий; другий залишився знизу:

  AlloctHwa       E, 1, HP2N	;; ПІДНЯТІ догори	xBrd+xAbn	 
  DefineCasIkm    E, 2, HP2 	;; КОМУТОВАНІ знизу	xBrd+xAbn

Підключення станцій з CAS-сигналізацією не потребує додаткових директив опису вузлів.

Опис каналів, напрямків та сотень

Всі канали описуються відносно точки підключення - а саме потоку, в якому вони розташовані - нема різниці який це потік - транзитно піднятий або комутований знизу.

Абонентські та з'єднувальні канали

Однією директивою можна описати один канал комутатора:

  LineAloc  xAbn,E2M, aon1,00, 0, Ft, AT,It,gww,Pram, 61  ;
  LineAloc  xAbn,E2N, aon1,01, 0,  0, AT,It,gww,Pram, 61  ;

Тут канали комутатора мають окремі номери та індивідуальні режими роботи. Також, однією директивою можна описати декілька каналів - якщо вони мають однакові режими роботи:

  MultiLine xAbn,E1 ,< MNOPQRSTUV >, ,20, <0,  Ft, AT,It, 0,Pram, 61>;;;

В цьому випадку, всі канали, починаючи з E1M, мають різні номери в сотні, починаючи з 20. Також, опис директивою MultiLine в подальшому забезпечує довільну зміну параметрів та режимів роботи каналів. Як правило, ця директива використовуються для опису абонентських каналів, яким якраз і потрібні різні номери в сотні та окремі налаштування.

Для опису з'єднувальних каналів використовується директива:

  TrunkLine ySs7,<C1,C2,D3>,<--2-4-6-8-A-C-E-G-I-K-M-O-Q-S-U->,,0,<wE,iNo,AU,It,0,Any,Stnd>

Ця директива створює групу каналів (в подальшому транк) з однаковими режимами роботи, які можна міняти тільки синхронно ; всі канали транку мають той самий номер - 00. Канали створюються в послідовності C12, C22, D32, C14, C24, D34, C16, . . . В цій самій послідовності вони і обробляються в напрямку.

В директиві опису транку можна не вказувати перелік каналів:

  TrunkLine  x1Dn,<F5,E6>, < >, aon1,  ,< 0, dOv, AT,It, 0,AonTat,CAS>

В цьому випадку, в транку будуть задіяні всі тональні з'єднувальні канали: а саме всі тональні, вказані у відповідних директивах опису потоків, крім описаними окремими директивами тональних транзитних. Для кожного з потоків цей перелік каналів може бути різним.

Кожний тональний канал, абонентський або з'єднувальний, має три посилання в таблицю аналізу номерів (як в останньому описі):

  • точка аналізу прямих номерів - AT;
  • точка аналізу зворотніх номерів (перевірка АВН) - AonTat;
  • додаткові параметри транків - CAS;

Внутрішні з'єднувальні канали

Ці канали використовуються для організації зв'язку з підлеглими БАДами та станціями по протоколу Ss7. Транк таких каналів описується директивою:

  InternalTrunkSs7    <H3,I4>,< >, BadS

Такий опис вимагає тільки одного параметру - точки аналізу зворотніх номерів (BadS). Тільки внутрішні канали мають необхідні попередньо налаштовані режими роботи та можливість обробки індексу точки аналізу прямих номерів. Остання властивість дозволяє на базі комутатора легко будувати “підкомутатори” з незалежною внутрішньою нумерацією.

Транзитні тональні канали

Транзитні канали описуються відразу парою - в одній директиві вказується обидва кінці транзитного з'єднання:

  TranzitPair  M6L,         0, N66,0   ;;
  TranzitPair  N3T,         0, N6R,0   ;;
  TranzitPair	 F1V,TzInvrArcv, N6V,TzNegaBtrn  ;;

В цій директиві також вказуються режими роботи кожного з каналів.

До транзитних каналів можна віднести і точки сигналізації:

  AlarmPoint   N6E,0   ;; Свиридівка

Це одиночний транзитний канал, який все, що приймає ззовні відразу й передає (закорочений для контролю). Стан цих каналів (все, що прийняте зовні) може контролюватися зовнішнім програмним забезпеченням.

Визначення напрямків

В напрямок включаються всі канали описані між директивами початку та кінця напрямку. Порядок переліку каналів у напрямку вельми суттєвий - від нього залежить черговість зайняття каналів при виході в даний напрямок. При визначенні напрямку можна відразу вказати і резервний до нього. Приклад опису двох напрямків:

      DirectionStrt        Bad5	;
  InternalTrunkSs7	<G3,H4>,< >
      DirectionEnds        Bad5
      DirectionStrt        Bad6	;
  InternalTrunkSs7	<H1,G2>,< >
      DirectionEnds        Bad6

Ще приклад опису опису двох напрямків:

      DirectionStrt   INET, ,INET_R
  TrunkLine  ySs7,<C5,C4>,<--2-4-6-8-A-C-E-G-I-K-M-O-Q-S-U->,1,,<wE,nPrdMj,O,It,0,All,SS7>
      DirectionEnds   INET
      DirectionStrt   INET_R
  TrunkLine  ySs7,<C5,C4>,<-1-3-5-7-9-B-D-F-H-J-L-N-P-R-T-V>,1,,<wE,nPr,   O,It,0,All,SS7>
      DirectionEnds   INET_R

Зверніть увагу, перший напрямок, INET, використовує другий напрямок, INET_R, як резервний. Для оптимізації маршрутів у внутрішній мережі необхідно що-би назви напрямків співпадали з назвами відповідних вузлів.

Визначення сотень

Сотня - це група каналів, що обслуговують вихід безпосередньо на абонентів. В сотню не можна включати транки - транк має тільки один номер на всі канали. В сотню включаються всі канали описані між директивами початку та кінця сотні або початком наступної сотні. Приклад опису десяти каналів в сотні PramE:

      HundredStart	610, PramE	;6102x;
  MultiLine xAbn,E1 ,< MNOPQRSTUV >, ,20, <0,  Ft, AT,It, 0,Pram, 61>;;
      HundredEnds	;; PramE

всі ці десять каналів отримають отримають номери 20 - 29 в поточній сотні.

Визначення абонентів стандартних сотень

На місці номера двозначного номера каналу в сотні можна вказувати його повний номер, як у прикладі:

    LineAloc  xAbn,I4N,aon1,"61480",0,Ft,A,Ic,gg,Any,61  ;
    LineAloc  xAbn,I4P,aon1,"61482",0,Ft,A,Ic,gg,Any,61  ;
    LineAloc  xAbn,I4R,aon1,"61485",0,Ft,A,Ic,gg,Any,61  ;
    LineAloc  xAbn,I4T,aon1,"61486",0,Ft,A,Ic,gg,Any,61  ;
    LineAloc  xAbn,I4V,aon1,"61487",0,Ft,A,Ic,gg,Any,61  ;
    LineAloc  xAbn,G5P,aon1,"65995",0,Ft,A,Ic,gg,Any,65  ;
    LineAloc  xAbn,G5Q,aon1,"65996",0,Ft,A,Ic,gg,Any,65  ;
    LineAloc  xAbn,I3U,aon1,"65997",0,Ft,A,Ic,gg,Any,65  ;
    LineAloc  xAbn,I3T,aon1,"65998",0,Ft,A,Ic,gg,Any,65  ;
    LineAloc  xAbn,C5P,aon1,"65999",0,Ft,A,Ic,gg,Any,65  ;

Всі ці канали попадуть в абонентські сотні з зарезервованими іменами, а саме Ab614 та Ab659 відповідно; ці сотні ніде описувати не треба.

До речі, перші п'ять каналів, що в сотні Ab614, можна було описати однією директивою:

  MultiLine xAbn,I4,<N-P--RTV>,aon1,"61480",0,Ft,A,Ic,gg,Any,61  ;

Порядок визначення таких абонентських каналів з повним номером не суттєвий - всі вони належать відповідним абонентськім сотням з зарезервованими іменами.

Правила аналізу номерів

Кожний абонентський або з'єднувальний канал має три посилання в таблицю аналізу номерів - аналіз прямого номера, аналіз зворотнього номера та параметрів транків. Правила аналізу номерів можуть вказуватись в довільному порядку, та в довільному місці файлу опису.

Аналіз прямих номерів

Аналіз прямих номерів (тих що канал приймає, наприклад, від абонента) здійснюється по правилах ForwardRule:

 ;; BAD1 - абоненти, спецслужби та десяток прямих абонентів
  ForwardRule AT  , "1-01"  , , #,          Bad1,  3, 0 ;101
  ForwardRule AT  , "1-02"  , , #,          Bad1,  3, 0 ;102
  ForwardRule AT  , "1-03"  , , #,          Bad1,  3, 0 ;103
  ForwardRule AT  , "1-06"  , , #,          Bad1,  3, 0 ;106
  ForwardRule AT  , "1-05"  , , #,          Bad1,  3, 0 ;105
  ForwardRule AT  , "1-04"  , , #,          Bad1,  3, 0 ;104
  ForwardRule AT  , "230"        , DrTownOnly, #,          Bad1,  5, 0 ;
  ForwardRule AT  , "231"        , DrTownOnly, #,          Bad1,  5, 0 ;
  ForwardRule AT  , "2320"       , DrTownOnly, #,          Bad1,  5, 0 ;
  ForwardRule AT  , "2321"       , DrTownOnly, #,          Bad1,  5, 0 ;
  ForwardRule AT  , "2322"       , DrTownOnly, #,          Bad1,  5, 0 ;
  ForwardRule AT  , "6101" , DrTownOnly, #,    Bad1,   5, 0 ;

Всі ці директиви ForwardRule забезпечують вихід в напрямок Bad1.

Приклад опису виходу в напрямок Bad3 у вигляді діапазону та виключення:

  ForwardRule  AT, "51(54-77)", DrTownOnly, #,       Bad3,  5,0
  ForwardRule  AT,!"51690",     DrTownOnly, -,Ab516,        5,0

Всі номери з діапазону 5154x - 5177x будуть направлені в напрямок Bad3, за виключенням номера 51690 - від буде направлений в сотню Ab516.

Ще приклад - організація виходу на міжмісто:

  ;; міжміський  напрямок >>> вихід на нього
  ForwardRule AT  , "00-xxxxxxxx", DrOverSeas, #,   AMTSN, -1, 0
  ForwardRule AT  , "01-00"      , DrTownOnly, #,InterNet, 10, 0 ;
  ForwardRule AT  , "01-0x"      , DrTownOnly, #,   AMTSN, 15, 0 ;
  ForwardRule AT  , "0112"       , DrOverTown, #,   AMTSN,  4, 0 ;
  ForwardRule AT  , "0118"       , DrOverTown, #,   AMTSN,  6, 0 ;
  ForwardRule AT  , "017"        , DrOverTown, #,   AMTSN,  4, 0 ;
  ForwardRule AT  , "018"        , DrOverTown, #,   AMTSN,  4, 0 ;
  ForwardRule AT  , "019"        , DrOverTown, #,   AMTSN,  4, 0 ;
  ForwardRule AT  , "02"         , DrOverTown, #,   OPTSN,  9, 0 ;  В ЦІЙ області 0-2-ab-*****
  ForwardRule AT  , "034"        , DrTownOnly, #,   OPTSN, 10, 0 ;; ЦЯ область
  ForwardRule AT  , "03x"        , DrTownOnly, #,   AMTSN, 10, 0 ;; області ІНШІ
  ForwardRule AT  , "0x"         , DrTownOnly, #,   AMTSN, 10, 0 ;; зони ІНШІ

Ще один приклад з виключеннями з діапазону одного номера та десятки номерів:

 ForwardRule  AT, "010050",        DrOverTown, #,  AMTS, 10,0
 ForwardRule  AT,!"010050-1111",  DrOverTown, #,  INTR, 10,0
 ForwardRule  AT,!"010050-999",   DrOverTown, #,  INTR, 10,0

А також приклад с заміною номера (“109” » “029909419”):

  ForwardRule  AT, "109",    DrTownOnly, $,     Tr109, 3
                         NumberTransform Tr109, "029909419", AT

Зверніть увагу на перший параметр AT попередніх директив - це початкова точка аналізу номера; для побудови функціонально повних таблиць аналізу номерів, бажано, що-би всі канали комутатора використовували одну точку аналізу. Вхідні міжміські канали, які не потребують функціональної повноти (від них заборонений вихід на міжмісто та спецслужби) можуть використовувати додаткову точку аналізу:

  ;; міжміський  напрямок >>> вхід з міжміста на абонентів комутатора
  ForwardRule AU  , "2[PDG,0]", DrTownOnly,  ,AT ;; Це тут !!!
  ForwardRule AU  , "3[PDG,0]", DrTownOnly,  ,AT ;; Це тут !!!
  ForwardRule AU  , "4[PDG,0]", DrTownOnly,  ,AT ;; Це тут !!!
  ForwardRule AU  , "6[PDG,0]", DrTownOnly,  ,AT ;; Це тут !!!
  ;; міжміський  напрямок >>> вхід з міжміста для організації контрольних заворотів
  ForwardRule AU  , "5"       , DrTownOnly, #, InterTel,  6, 0	;; заворот для контролю
  ForwardRule AU  , "7"       , DrTownOnly, #, InterNet,  6, 0
  ForwardRule AU  , "8"       , DrTownOnly, #,    OPTSN,  6, 0
  ForwardRule AU  , "9"       , DrTownOnly, #,    AMTSN,  6, 0

Додаткова точка аналізу номера (нижче в прикладі Offis) може використовуватись для організації “офісної АТС”, яка розпорошена на декількох БАДах комутатора:

  ForwardRule Offis , "(90-93)" , DrTownOnly, #,  Bad2,  3, 0   ;; 900 - 939
  ForwardRule Offis , "(94-95)" , DrTownOnly, #,  Bad3,  3, 0   ;; 940 - 959
  ForwardRule Offis , "96"      , DrTownOnly, #,  Bad4,  3, 0   ;; 960 - 969
  ForwardRule Offis , "(97-98)" , DrTownOnly, #,  Bad5,  3, 0   ;; 970 - 989
  ForwardRule Offis , "x[PDG,0]"   , ,  ,AT ;; як для всіх

Для правильної взаємодії комутаторів та БАДів в режимі “офісної АТС” необхідно що-би вони були з'єднані внутрішніми каналами ySs7 (дивись InternalTrunkSs7) та мали однаковий список глобальних точок аналізу номеру у директиві:

  MakeForwardTables  <AT,Offis,Find>

Зверніть увагу, точка аналізу AU (від міжміських каналів) в цій директиві не вказана - вона локалізована в межах самого комутатора та нікуди не передається. В описі комутатора допускається тільки одна директива MakeForwardTable!

Перевірка АВН

Для опису правил перевірки зворотнього номера (джерела виклику) використовуються директиви:

  BackwardRule PolyRul, "380-55-3437xxx", +
  BackwardRule PramAon, "380-5534-6102x", +  ;; АОН на десяток
  BackwardRule Vam2BWR, "380-5534-216xx", +
  BackwardRule Vam2BWR, "380-5534-217xx", +
  BackwardRule Vam2BWR, "380-5534-218xx", +

В цих директивах перший параметр - початкова точка аналізу зворотнього номера; ця назва вказується в описі каналів. Бажано, щоб ця назва своїм початком співпадала з назвою напрямку, звідки прийшов цей виклик. Зверніть увагу - початок шаблону аналізу номерів повинен відповідати початку шаблонів номерів в описах транків; оптимально, коли ці номери починаються з зонового номеру комутатора. Останні три директиви можна замінити на одну “діапазонну”:

  BackwardRule Vam2BWR, "380-5534-(216-218)xx", +

Для створення таблиці перевірки АВН використовується директива:

  MakeBackwardTables

Директива створює спільну таблицю правил перевірки АВН. В описі може бути тільки одна ця директива.

Параметри транків

При використанні стандартних налаштувань параметрів транків їх можна описувати однією директивою:

  TrunkExtraPar   61, "380-5534-61xxx" ;; для прямих абонентів
  TrunkExtraPar  CAS, "380-5534-xxxxx" ;; для всіх CAS

Ці директиви описують стандартне налаштування параметрів транків з назвами 61 та СAS.

Віртуальні канали та блоки

Віртуальний канал - це такій канал, який не має та не потребує фізичних ресурсів комутатора; віртуальні канали групуються в блоки. Віртуальні канали виконують функції автовідповідача (vAnw), автозапитувача (vZpr) та канала із зовнішнім керуванням (vZs7).

Блок віртуальних каналів визначається директивою:

 AlloctTract ZY, ,Vrt,2 ;; віртуальний

В ній вказується місце посадки каналів - ZY - та які саме канали визначені. Віртуальні канали визначають аналогічно звичайним фізичним:

  LineAloc   vZs7,ZY1,aon0,00,   0,0,AT, 0,0,  AnyBWR,Home
  LineAloc   vAnw,ZY2,aon0,39,   0,0,AU,it,0,  AnyBWR,Home

Додаткові описи комутатора

Адреса технологічного доступу до комутатора в IP-мережі визначається директивою:

  DefineIPNet	<000h,008h,002h,094h,02Bh,0CCh>,<192,168,000,004>,0e800h

Директива DefineModem використовується для вказування паролю з'єднання через модем. Довжина паролю 8 символів.

  DefineModem	**Serg**

Визначення паролю для встановлення напівпостійних з'єднань:

  DefineParol    ********,1

Текст опису таблиці ліній комутатора визначається директивою:

  DefineStationLin    15,'Внутрішні канали тільки Ss7, зовнішні - будь-які '	;;

Текст опису таблиці нумерації комутатора визначається директивою:

  DefineStationNmr    15,'ТЕСТ Генератора станцій; Повний аналіз номера '	;;

Визначення ключа перепрограмування комутатора:

  TableCryptKey       <0123-4567-89AB-cdef-4444-4567-89ab-cdEF>

Приклади підключення

Вузли вищого рівня

Нижче приведено приклад опису інтерфейсу підключення комутатора до декількох вузлів вищого рівня

  ;#####################################################################
  ;	вихід на зовнішні Oks --- вихід на область 
  ;;================================================================
    ConnectOksNode  AMTS, <Nat,16, 3, 0>, <C1,C2,C4,D2,D3>,<C11>, <OPTS> ; на AMTS
    ConnectOksNode  OPTS, <Nat,16, 0, 0>, <D1>,            <D11>, <AMTS> ; на OPTS
    ConnectOksNode  INTR, <Nat,16, 7, 2>, <C3,D4>,< >, <OPTS,AMTS>	; на INET
    ConnectOksNode  ITK,  <Nat,16, 6, 0>, <D6>,   < >, <OPTS,AMTS>	; на ITK
  ;=====================================================================
      AlloctOksHway C,1,H
      AlloctOksHway C,2,H
      AlloctOksHway C,3,H
      AlloctOksHway C,4,H
      AlloctOksHway D,1,H
      AlloctOksHway D,2,H
      AlloctOksHway D,3,H
      AlloctOksHway D,4,H
      AlloctOksHway D,6,H
SetLinkModes   <C11,D11>, -T1
  ;*********************************************************************

Опис напрямків такий:

        DirectionStrt    AMTS, 0,AMTSv ;;  з резервом
  TrunkLine ySs7,<C1,D3>,<--2-4-6-8-A-C-E-G-I-K-M-O-Q----->,aon1,,<wE,dIn+bM,Au,Ic,Rg,ALL,Abn>  
  TrunkLine ySs7,<D3>,   <SU>,aon1,00,<wE,dIn+bM,A,Ic,RgMSS>,ALL,Abn  
  TrunkLine ySs7,<C4,D2>,<--2-4-6-8-A-C-E-G-I-K-M-O-Q-S-U->,aon1,,<wE,dIn+bM,Au,Ic,Rg,ALL,Abn>  
  TrunkLine  ySs7,<C2>,  <--2-4-6-8-A-C-E-G-I-K-M-O-Q-S-U->,aon1,,<wE,dIn+bM,Au,Ic,Rg,ALL,Abn>  
        DirectionEnds    AMTS
        DirectionStrt    AMTS08, 0
  TrunkLine ySs7,<C1>,   <UV>,aon1,,<wE,dIn,Au,It,Rg,ALL,Abn>  
        DirectionEnds    AMTS08
        DirectionStrt    AMTS09, 0
  TrunkLine ySs7,<C1>,   <ST>,aon1,,<wE,dIn,Au,It,Rg,ALL,Abn>  
        DirectionEnds    AMTS09
        DirectionStrt    AMTSv, 0
  TrunkLine ySs7,<C1>,   <----R-P-N-L-J-H-F-D-B-9-7-5-3--->,aon1,,<wE,dIn,Au,Ic,Rg,ALL,Abn>  
  TrunkLine ySs7,<D3>,   <V-T-R-P-N-L-J-H-F-D-B-9-7-5-3-1->,aon1,,<wE,dIn,Au,Ic,Rg,ALL,Abn>  
  TrunkLine ySs7,<C4,D2>,<V-T-R-P-N-L-J-H-F-D-B-9-7-5-3-1->,aon1,,<wE,dIn,Au,Ic,Rg,ALL,Abn>  
  TrunkLine ySs7,<C2>,   <V-T-R-P-N-L-J-H-F-D-B-9-7-5-3-1->,aon1,,<wE,dIn,Au,Ic,Rg,ALL,Abn>  
        DirectionEnds    AMTSv
        DirectionStrt    OPTS, 0
  TrunkLine ySs7,<D1>,   <--23456789ABCDEFGHIJKLMNOPQRSTUV>,aon1,,<wE,dIn+bM,Au,Ic,Rg,ALL,Abn>  
        DirectionEnds    OPTS
        DirectionStrt    INTR, 0
  TrunkLine  ySs7,<C3>,  <VUTSRQPONMLKJIHGFEDCBA987654321->,aon1,,<wE,dIn,Au,It,Rg,ALL,Abn>  
  TrunkLine  ySs7,<D4>,  <VUTSRQPONMLKJIHGFEDCBA987654321->,aon1,,<wE,dIn,Au,It,Rg,ALL,Abn>  
        DirectionEnds    INTR
        DirectionStrt    ITK, 0,ITKv  ;; з резервом
  TrunkLine  ySs7,<D6>,  <--2-4-6-8-A-C-E-G-I-K-M-O-Q-S-U->,aon1,,<0,dIn+bM,Au,Ic,Rg,ALL,Abn>  
        DirectionEnds    ITK
        DirectionStrt    ITKv, 0
  TrunkLine  ySs7,<D6>,  <V-T-R-P-N-L-J-H-F-D-B-9-7-5-3-1->,aon1,,<0,dIn,Au,Ic,Rg,ALL,Abn>  
        DirectionEnds    ITKv

В приведених прикладах використовується нестандартна послідовність каналів в напрямках - парні/непарні та в зворотній послідовності - тому і явно вказані всі канали.

Підлеглий БАД

Нижче приведено фрагмент підключення підлеглого вузла з назвою Bad2:

  ;;################################################################
  ;;################################################################
  ;; підлеглий БАД2
  ;;##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==
      ConnectOksPeer  Bad2, < 1,1,0 >, <C5>, <C5G>
      ConnectOksPeer  Bad2, < 1,1,0 >, <E2>, <E2G>
  ;-----------------------------------------------------------------
            DirectionStrt    Bad2,0 ;;  БЕЗ резерву - циклічний перебір
      InternalTrunkSs7 <C5,E2>,< >
            DirectionEnds    Bad2
  ;-----------------------------------------------------------------
     ForwardRule  A, "485(240-479)", DrTownOnly, #, Bad2,  6,0 ;; == 240
     ForwardRule  A, "486275",       DrTownOnly, #, Bad2,  6,0 ;; ==   1
  ;;##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==
  ;;################################################################
  ;;################################################################

На початку фрагменту дві директиви ConnectOksPeer вказують поінт-код вузла Bad2 та конфігурації двох незалежних тонал-сетів з лінк-сетом. Далі директива InternalTrunkSs7 вказує перелік каналів, які використовуються для виходу на цей вузол - всі що є в потоках. І, нарешті, директиви ForwardRule визначають номерну ємність закріплену за цим БАДом.

Цей опис може бути доповнений описом внутрішньої (не інтерфейсної) частини самого БАДу:

  ;;################################################################
  ;;################################################################
  ;;##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==
  insertbeg Bad2  ;; абонентська частина - вставляється в шаблони
  ;===================================================
  Model:    Name = Bad2    ;; назва цього баду для маршрутів
  ;;......................................
     AlloctTract     B, ,Mtu,0 ;; без каналів
     AlloctTract     <C,D,E,F, G,H,I,J, K,L,M,N, O,P,Q,R>, ,Akf ; 16 плат 
     AlloctTract Z,Z,Vrt,2,<-1> ;; віртуальний
  ;;......................................
        DirectionStrt 486xxx
  LineAloc  aAbn,MA, aon3,"486275",  0, Ft, A,Ic,wRgt,Any,486 ;;!! ВИБИВАЄ канал MA з MultiLine
        DirectionEnds 486xxx
        DirectionStrt 485xxx
  MultiLine aAbn,<C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R>,< >,aon3,"485240",<0, Ft, A,Ic,wRgt,Any,485>
  LineAloc  vAnw,ZZ1,aon3,"485399",  0, Ft, A,Ic,wRgt,Any,485       ; AutoAnswer 
        DirectionEnds 485xxx
  ;;==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  
  insertend   ;; BAD2
  ;;##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==
  ;;################################################################
  ;;################################################################

В процесі роботи програми обробки весь текст між директивами insertbeg/insertend без жодної обробки буде вставлений в файл шаблонів для вузла Bad2.

Підключення по PRI

Показано підключення двох станцій:

  ;;################################################################
  ;;################################################################
  ;; оператор з PRI
  ;-----------------------------------------------------------------
      DefinePriIkm	N, 5,H,22,<-123456789ABCDEF-HIJKL>
  	SetLinkModes <N5G>,     -T1N	;; /U
       DirectionStrt   OPERATOR, 0,Blizko
  TrunkLine  yDss,N5,< >, 1,15, <0,  0, A,Ic,gg,OperBWR,Tetijiv>
  	 DirectionEnds   OPERATOR
     BackwardRule  OperBWR,     ".Z.65(0-1)", +
     ForwardRule  A, "65(000-199)", DrTownOnly, #,OPERATOR,  5,0
  ;=================================================================
      DefinePriIkm	N, 6,H
  	SetLinkModes <N6G>,     -T1N	;; /U
       DirectionStrt   Blizko
  TrunkLine  yDss,N6,< >, 1,15, <0,  0, A,Ic,gg,BlizBWR,Tetijiv>
  	 DirectionEnds   Blizko
     BackwardRule  BlizBWR,     ".Z.65(2-4)", +
     ForwardRule  A, "65(200-499)", DrTownOnly, #,Blizko,  5,0
  ;;################################################################
  ;;################################################################

В першої станції використовуються не всі канали в потоці та вона використовує канали другої як резервні.

Підключення по CAS

  ;;################################################################
  ;;	підключення комутованих CAS
  ;-----------------------------------------------------------------
  iDc        = IkModDecad	; декадний прийом/передача
  Nsp        = IsUsePream	; перевіряє и відкидає преамбулу передачі
  ;=================================================================
      AlloctHwa I,3,HP1;;;
      DirectionStrt    Susidy, 0
        TrunkLine  x1Dn,<I3>,< >,aon1,,<0,iDc,AskBPI,Ic,gg,Dcd655,CAS>,<ExtraNumer **,65,Nsp>
        TranzitPair  I3V,0,G5T,0
      DirectionEnds    Susidy
     BackwardRule  Dcd655,     ".Z.65(5-7)", +
  ;=================================================================
      AlloctHwa I,4,HP1
  ;-----------------------------------------------------------------
      DirectionStrt    Remesh, 0 ;; на A
        TranzitPair  I4K,0,G5V,0 ;; сигналізація - ПРІОРИТЕТНО вибита
        TrunkLine x1Dn,<I4>,<-U-S-Q-O-M---I--F-D-B-9-7-5-3-1->,aon1,,<0,iDc,AskBPI,Ic,gg,Dcd658,CAS>,<ExtraNumer **,65,Nsp>
      DirectionEnds    Remesh
     BackwardRule  Dcd658,     ".Z.658", +
  ;-----------------------------------------------------------------
      DirectionStrt    Rokish, 0 ;; на B
        TrunkLine x1Dn,<I4>,<------------J-H--E-C-A-8-6-4-2-->,aon1,00,<0,iDc,AskBPI,Ic,gg,Dcd659,CAS>,<ExtraNumer **,65,Nsp>
        TranzitPair  I4L,0,G5U,0 ;; сигналізація - ПРІОРИТЕТНО вибита
  	  DirectionEnds  Rokish
     BackwardRule  Dcd659,     ".Z.659", +
  ;=================================================================
  ;; вихід в ці декади
     ForwardRule  A, "65(5-7)",     DrTownOnly, #,  Susidy,  5,0 ;; три сотні
     ForwardRule  A, "658",         DrTownOnly, #,  Koshiv,  5,0
     ForwardRule  A, "659(0-6)",    DrTownOnly, #,  Rokish,  5,0 ;; сім десятків
  ;;################################################################

Кожна зі станцій використовує по одному каналу сигналізації; дві останні малономерні станції сидять на одному потоці I4.

Прямі абоненти

Приклад опису підключення прямих абонентів та віртуальних каналів:

  ;;################################################################
        ;; купа для прямих абонентів на каналах CAS знизу
  ;;==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==
  Ft         = FnModTonal        ;; тональный набор
      LineAloc  xAbn,I4N,aon1,"65980",0,Ft,A,Ic,gg,Any,65  ;65980 
      LineAloc  xAbn,I4P,aon1,"65982",0,Ft,A,Ic,gg,Any,65  ;65982
      LineAloc  xAbn,I4R,aon1,"65985",0,Ft,A,Ic,gg,Any,65  ;65987
      LineAloc  xAbn,I4T,aon1,"65986",0,Ft,A,Ic,gg,Any,65  ;65991
      LineAloc  xAbn,I4V,aon1,"65987",0,Ft,A,Ic,gg,Any,65  ;65993
      LineAloc  xAbn,G5P,aon1,"65995",0,Ft,A,Ic,gg,Any,65  ;
      LineAloc  xAbn,G5Q,aon1,"65996",0,Ft,A,Ic,gg,Any,65  ;
      LineAloc  xAbn,I3U,aon1,"65997",0,Ft,A,Ic,gg,Any,65  ;
      LineAloc  xAbn,I3T,aon1,"65998",0,Ft,A,Ic,gg,Any,65  ;
      LineAloc  xAbn,C5P,aon1,"65999",0,Ft,A,Ic,gg,Any,65  ;знизу - окремий канал Matvij
      ;; віртуальні в сотні розкиданих каналів 
    LineAloc  vZs7,ZY1,aon1,"65988",0,0,A,It,0,Any,65
                          ExtraNumer   ZY1, 65989 ; 
                          ExtraNumer   ZY1, 65989 ; 
                          ExtraNumer   ZY1, 65989
    LineAloc  vAnw,ZY2,aon1,"65989",0,0,A,Ic,0,Any,65
  ;-----------------------------------------------------------------
  ;; два десятки для них 
     ForwardRule  A, "659(8-9)",    DrTownOnly, -,  Ab659,  5,0  ;; два десятки
  ;-----------------------------------------------------------------
     TrunkExtraPar 65, ".Znu.65xxx"  , < .Geo. >; Україна, Київська область, Тетіїв
  ;;==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==
  ;;  взагалі особливий золотий 
     ForwardRule  A,!"66666", DrTownOnly, -,Ab666,  5,0
      LineAloc  xAbn,C5O,aon1,"66666",0,Ft,A,Ic,gg,Any,66  ;знизу - окремий канал Matvij
     TrunkExtraPar 66, ".Znu.66xxx"  , < .Geo. >; Україна, Київська область, Тетіїв
  ;;################################################################

У всіх цих каналів явно вказані номери - вони попадуть в сотні зі стандартними іменами Ab659 та Ab666 - ці сотні створюються по замовчування.

Типовий опис ресурсів об'єкту

Приклад опису взаємодії комутатора з підлеглим багатофункціональним БАДом (весь опис в одному файлі!):

;;=== === === === === === === === === === === === === === === === 
  ConnectOksPeer  BAD1, < 3,00,0>, <G1,H2>,<G1G,H2G>
  AlloctOksPass G,1,H
  AlloctOksPass H,2,H
SetLinkModes    <G1G,H2G>, -T1L
;;=== === === === === === === === === === === === === === === === 
        DirectionStrt    BAD1,0
  InternalTrunkSs7 <G1,H2>,< >
        DirectionEnds    BAD1
;;##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==
;; прості абоненти БАДу
 ForwardRule  A, "70(000-219)",DrTownOnly, #, BAD1,  5,0 ;; 220 номерів
    ;; BAD1 - спецслужби
 ForwardRule AT  , "1-01"  , , #,          Bad1,  3, 0 ;101
 ForwardRule AT  , "1-02"  , , #,          Bad1,  3, 0 ;102
 ForwardRule AT  , "1-03"  , , #,          Bad1,  3, 0 ;103
 ForwardRule AT  , "1-06"  , , #,          Bad1,  3, 0 ;106
 ForwardRule AT  , "1-05"  , , #,          Bad1,  3, 0 ;105
 ForwardRule AT  , "1-04"  , , #,          Bad1,  3, 0 ;104
    ;; BAD1 - десяток прямих абонентів
 ForwardRule AT  , "6101" , DrTownOnly, #,    Bad1,   5, 0 ;
;;##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==##==
;; Зворотній номер від БАДу не перевіряти !!!!!
;. . . . . . . . . . . . . . . . . . . . . . .

Приклад опису виходу на підлеглі станції по сигналізаціям Cas - три маленьких станції на одному потоці:

;;###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=
;; один потік на три станції - не всі каналі використовуються
 AlloctHwa   D,5, HP2N0, 0E,0K,32,    <-123456789ABCD---HIJKLMNOPQ-----> ; N_Bur,Borsh, N_Kom
;;###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=
;; D5  -- Новий Бурлук --  підключено по CAS
;;==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  
   ForwardRule  A, "442",        DrTownOnly, #,      N_Bur,  5,0
;;--  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --
        DirectionStrt    N_Bur
 TrunkLine  x1Dn,<D5>,<-1234------------HIJ------------>,1,1,<0,iDb,A,Is,gwt+git,442Dcd,CAS44>  ,<ExtraNumer **, 44,IsUsePream> 
        DirectionEnds    N_Bur
;;--  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --
 BackwardRule  442Dcd,     ".Znu.442", +
;;###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=
;; D5  -- Борщова --  підключено по CAS
;;==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  
 ForwardRule  A, "412",        DrTownOnly, #,      Borsh,  5,0
;;--  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --
        DirectionStrt    Borsh
 TrunkLine  x1Dn,<D5>,<------67--------------MN-------->,1,1,<0,iDb,A,Is,gwt+git,412Dcd,CAS41>  ,<ExtraNumer **, 41,IsUsePream> 
        DirectionEnds    Borsh
;;--  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --
 BackwardRule  412Dcd,     ".Znu.412", +
;;###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=
;; D5  -- Н.Комсомольске --  підключено по CAS
;;==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  
 ForwardRule  A, "492",        DrTownOnly, #,      N_Kom,  5,0
;;--  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --
        DirectionStrt    N_Kom
  TrunkLine  x1Dn,<D5>,<---------9AB------------OPQ----->,1,1,<0,iDb,A,Is,gwt+git,492Dcd,CAS67>  ,<ExtraNumer **, 49,IsUsePream>1,3,17
        DirectionEnds    N_Kom
;;--  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --  --
 BackwardRule  492Dcd,     ".Znu.492", +
;;###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=

Приклад опису підключення вузла з авто-інформатором спецслужб:

;;################################################################
;; на станцію з DSS -- номера 108 та 119
;;###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=###=
 ForwardRule  A, "108",        DrTownOnly, #,       AvIn,  3,0  ;; спецслужба DSS
 ForwardRule  A, "119",        DrTownOnly, #,       AvIn,  3,0  ;; спецслужба DSS
;;=== === === === === === === === === === === === === === === === 
       ;; задіяно тільки 5 тональних каналів
DefinePriIkm C,4,H,6,<-12345>
 	SetLinkModes <C4G>,     -T1N
;;=== === === === === === === === === === === === === === === === 
NoCpn = DsModNoPrs    ;не представляти номер абонента
It = DrInternal+DrTownOnly+DrOverTown+DrOverSeas+DrNoCharge+DrCharging ; для першої категорії
DirectionStrt   AvIn
TrunkLine  yDss,C4,<>, 1,  , <0,NoCpn,A,It,0,Any,Pechenigy>
DirectionEnds   AvIn
;;################################################################

Приклад опису підключення прямих абонентських каналів:

;;################################################################
;; абоненти на каналах різних потоків 
;;=== === === === === === === === === === === === === === === === 
  LineAloc  xAbn,I1D,5,"76911",0,Ft,A,It,0,Any,76 ;13  25 12.06.2007
  LineAloc  xAbn,I1F,5,"76916",0,Ft,A,It,0,Any,76 ;13  25 12.06.2007
  LineAloc  xAbn,I1U,5,"76924",0,Ft,A,It,0,Any,76 ;13  26 12.06.2007
  LineAloc  xAbn,I1Q,5,"76923",0,Ft,A,It,0,Any,76  
  LineAloc  xAbn,F3U,3,"76900",0,Ft,A,It,0,Any,76  ;
  LineAloc  xAbn,K2D,1,"76940",0,Ft,A,It,0,Any,76  ;
  LineAloc  xAbn,I6O,1,"76983",0,Ft,A,It,0,Any,76  ;
  LineAloc  xAbn,I6S,1,"76982",0,Ft,A,It,0,Any,76  ;
  LineAloc  xAbn,I6U,1,"76983",0,Ft,A,It,0,Any,76  ;
  LineAloc  xAbn,F3M,1,"76905",0,Ft,A,It,0,Any,76  ;
  LineAloc  xAbn,I1C,5,"76917",0,Ft,A,It,0,Any,76  ;
  LineAloc  xAbn,E5V,1,"76941",0,Ft,A,It,0,Any,76  ;
  LineAloc  xAbn,I1V,5,"76922",0,Ft,A,It,0,Any,76  ;13  28 12.06.2007
  LineAloc  xAbn,D4N,3,"76905",0,Ft,A,It,0,Any,76  ;S
  LineAloc  xAbn,E5U,3,"73917",0,Ft,A,It,0,Any,73  ; !!!!! один в цій тисячі
  LineAloc  xAbn,F6J,1,"78939",0,Ft,A,It,0,Any,78 ;   19  26 11.07.2006
  LineAloc  xAbn,F6T,1,"78933",0,Ft,A,It,0,Any,78 ;  19  29 11.07.2006
;;==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==
;;  правила виходу в сотні прямих абонентів
  ForwardRule  A, "739xx",    DrTownOnly, -,  Ab739,  5,0
  ForwardRule  A, "769xx",    DrTownOnly, -,  Ab769,  5,0
  ForwardRule  A, "789xx",    DrTownOnly, -,  Ab789,  5,0
;;==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==  ==
;; транк групи тисяч
 TrunkExtraPar 73, ".Znu.73xxx"  , < .Geo. > ; Україна, Львівська обл
 TrunkExtraPar 76, ".Znu.76xxx"  , < .Geo. > ; Україна, Львівська обл
 TrunkExtraPar 78, ".Znu.78xxx"  , < .Geo. > ; Україна, Львівська обл
;;################################################################

Приклад опису транзитних каналів та точок сигналізації:

;;################################################################
;;	Точки сигналізації
    AlarmPoint   E33,0
    AlarmPoint   G6Q,0
    AlarmPoint   H6B,0
    AlarmPoint   H6U,0
    AlarmPoint   E36,0
    AlarmPoint   G6R,0
    AlarmPoint   H6E,0
;;	Транзитні пари
    TranzitPair  E31,0,G6U,0
    TranzitPair  E5U,0,H65,0
    TranzitPair  F4F,0,G69,0
    TranzitPair  F5F,0,G65,0
    TranzitPair  F6F,0,G61,0
    TranzitPair  G2K,0,G6K,0
    TranzitPair  G3M,0,G6F,0
    TranzitPair  G4F,0,G6B,0
    TranzitPair  G5F,0,G67,0
    TranzitPair  G5S,0,G6D,0
    TranzitPair  G63,0,H4Q,0
    TranzitPair  G6O,0,H4F,0
    TranzitPair  G6S,0,H3F,0
    TranzitPair  H2S,0,H67,0
    TranzitPair  H2U,0,H69,0
    TranzitPair  E34,0,G6T,0
    TranzitPair  E3E,0,H62,0
    TranzitPair  E5V,0,H64,0
  ====    ====    ====    ====    ====    ====    ====    ====    ====    ====
      ====    ====    ====    ====    ====    ====    ====    ====    ====
  ====    ====    ====    ====    ====    ====    ====    ====    ====    ====

Порядок створення файлу опису комутатора

Сбір загальної інформації про комутатор

  1. Назва проекту - Zolochiv - типова назва для прикладу.
  2. Номер проекту - 259 - потрібен тільки для сумістності зі старими проектами, що би використовувати старі .bat-файли для створення .bin та .tbl файлів.
  3. Зоновий номер комутатора - “380-3265-“ - ЗОНОВИЙ формат для МІСЦЕВИХ ліній та “380-3265xxxxx-“ - НАЦІОНАЛЬНИЙ формат для МІЖМІСЬКИХ ліній.
  4. Визначити поінт-код пункту сигналізації Zolochiv в національній мережі - Nat,07,17,1.
  5. Визначити географічні координати пункту сигналізації Zolochiv - знадобляться потім коли вони будуть передаватися по національній мережі.
  6. Визначити поінт-коди вище-стоячих пунктів сигналізації в національній мережі.
  7. Визначити схеми підключення до вище-стоячих вузлів: потоки, лінки, тонал-сети, напрямки та тональні канали.
es11soft/groupconfig/comopis.txt · В останнє змінено: 2015/04/17 15:23 (зовнішнє редагування)